[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [Top] [Contents] [Index] [ ? ]

25. Files

In Emacs, you can find, create, view, save, and otherwise work with files and file directories. This chapter describes most of the file-related functions of Emacs Lisp, but a few others are described in 27. Buffers, and those related to backups and auto-saving are described in 26. Backups and Auto-Saving.

Many of the file functions take one or more arguments that are file names. A file name is actually a string. Most of these functions expand file name arguments by calling expand-file-name, so that `~' is handled correctly, as are relative file names (including `../'). These functions don't recognize environment variable substitutions such as `$HOME'. See section 25.8.4 Functions that Expand Filenames.

When file I/O functions signal Lisp errors, they usually use the condition file-error (see section Writing Code to Handle Errors). The error message is in most cases obtained from the operating system, according to locale system-message-locale, and decoded using coding system locale-coding-system (see section 33.12 Locales).

25.1 Visiting Files  Reading files into Emacs buffers for editing.
25.2 Saving Buffers  Writing changed buffers back into files.
25.3 Reading from Files  Reading files into buffers without visiting.
25.4 Writing to Files  Writing new files from parts of buffers.
25.5 File Locks  Locking and unlocking files, to prevent simultaneous editing by two people.
25.6 Information about Files  Testing existence, accessibility, size of files.
25.7 Changing File Names and Attributes  Renaming files, changing protection, etc.
25.8 File Names  Decomposing and expanding file names.
25.9 Contents of Directories  Getting a list of the files in a directory.
25.10 Creating and Deleting Directories  
25.11 Making Certain File Names "Magic"  Defining "magic" special handling for certain file names.
25.12 File Format Conversion  Conversion to and from various file formats.

[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [Top] [Contents] [Index] [ ? ]

25.1 Visiting Files

Visiting a file means reading a file into a buffer. Once this is done, we say that the buffer is visiting that file, and call the file "the visited file" of the buffer.

A file and a buffer are two different things. A file is information recorded permanently in the computer (unless you delete it). A buffer, on the other hand, is information inside of Emacs that will vanish at the end of the editing session (or when you kill the buffer). Usually, a buffer contains information that you have copied from a file; then we say the buffer is visiting that file. The copy in the buffer is what you modify with editing commands. Such changes to the buffer do not change the file; therefore, to make the changes permanent, you must save the buffer, which means copying the altered buffer contents back into the file.

In spite of the distinction between files and buffers, people often refer to a file when they mean a buffer and vice-versa. Indeed, we say, "I am editing a file," rather than, "I am editing a buffer that I will soon save as a file of the same name." Humans do not usually need to make the distinction explicit. When dealing with a computer program, however, it is good to keep the distinction in mind.

25.1.1 Functions for Visiting Files  The usual interface functions for visiting.
25.1.2 Subroutines of Visiting  Lower-level subroutines that they use.

[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [Top] [Contents] [Index] [ ? ]

25.1.1 Functions for Visiting Files

This section describes the functions normally used to visit files. For historical reasons, these functions have names starting with `find-' rather than `visit-'. See section 27.4 Buffer File Name, for functions and variables that access the visited file name of a buffer or that find an existing buffer by its visited file name.

In a Lisp program, if you want to look at the contents of a file but not alter it, the fastest way is to use insert-file-contents in a temporary buffer. Visiting the file is not necessary and takes longer. See section 25.3 Reading from Files.

Command: find-file filename &optional wildcards
This command selects a buffer visiting the file filename, using an existing buffer if there is one, and otherwise creating a new buffer and reading the file into it. It also returns that buffer.

The body of the find-file function is very simple and looks like this:

(switch-to-buffer (find-file-noselect filename))

(See switch-to-buffer in 28.7 Displaying Buffers in Windows.)

If wildcards is non-nil, which is always true in an interactive call, then find-file expands wildcard characters in filename and visits all the matching files.

When find-file is called interactively, it prompts for filename in the minibuffer.

Function: find-file-noselect filename &optional nowarn rawfile wildcards
This function is the guts of all the file-visiting functions. It finds or creates a buffer visiting the file filename, and returns it. It uses an existing buffer if there is one, and otherwise creates a new buffer and reads the file into it. You may make the buffer current or display it in a window if you wish, but this function does not do so.

If wildcards is non-nil, then find-file-noselect expands wildcard characters in filename and visits all the matching files.

When find-file-noselect uses an existing buffer, it first verifies that the file has not changed since it was last visited or saved in that buffer. If the file has changed, then this function asks the user whether to reread the changed file. If the user says `yes', any changes previously made in the buffer are lost.

This function displays warning or advisory messages in various peculiar cases, unless the optional argument nowarn is non-nil. For example, if it needs to create a buffer, and there is no file named filename, it displays the message `(New file)' in the echo area, and leaves the buffer empty.

The find-file-noselect function normally calls after-find-file after reading the file (see section 25.1.2 Subroutines of Visiting). That function sets the buffer major mode, parses local variables, warns the user if there exists an auto-save file more recent than the file just visited, and finishes by running the functions in find-file-hooks.

If the optional argument rawfile is non-nil, then after-find-file is not called, and the find-file-not-found-hooks are not run in case of failure. What's more, a non-nil rawfile value suppresses coding system conversion (see section 33.10 Coding Systems) and format conversion (see section 25.12 File Format Conversion).

The find-file-noselect function usually returns the buffer that is visiting the file filename. But, if wildcards are actually used and expanded, it returns a list of buffers that are visiting the various files.

(find-file-noselect "/etc/fstab")
     => #<buffer fstab>

Command: find-file-other-window filename &optional wildcards
This command selects a buffer visiting the file filename, but does so in a window other than the selected window. It may use another existing window or split a window; see 28.7 Displaying Buffers in Windows.

When this command is called interactively, it prompts for filename.

Command: find-file-read-only filename &optional wildcards
This command selects a buffer visiting the file filename, like find-file, but it marks the buffer as read-only. See section 27.7 Read-Only Buffers, for related functions and variables.

When this command is called interactively, it prompts for filename.

Command: view-file filename
This command visits filename using View mode, returning to the previous buffer when you exit View mode. View mode is a minor mode that provides commands to skim rapidly through the file, but does not let you modify the text. Entering View mode runs the normal hook view-mode-hook. See section 23.6 Hooks.

When view-file is called interactively, it prompts for filename.

Variable: find-file-wildcards
If this variable is non-nil, then the various find-file commands check for wildcard characters and visit all the files that match them. If this is nil, then wildcard characters are not treated specially.

Variable: find-file-hooks
The value of this variable is a list of functions to be called after a file is visited. The file's local-variables specification (if any) will have been processed before the hooks are run. The buffer visiting the file is current when the hook functions are run.

This variable works just like a normal hook, but we think that renaming it would not be advisable. See section 23.6 Hooks.

Variable: find-file-not-found-hooks
The value of this variable is a list of functions to be called when find-file or find-file-noselect is passed a nonexistent file name. find-file-noselect calls these functions as soon as it detects a nonexistent file. It calls them in the order of the list, until one of them returns non-nil. buffer-file-name is already set up.

This is not a normal hook because the values of the functions are used, and in many cases only some of the functions are called.

[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [Top] [Contents] [Index] [ ? ]

25.1.2 Subroutines of Visiting

The find-file-noselect function uses two important subroutines which are sometimes useful in user Lisp code: create-file-buffer and after-find-file. This section explains how to use them.

Function: create-file-buffer filename
This function creates a suitably named buffer for visiting filename, and returns it. It uses filename (sans directory) as the name if that name is free; otherwise, it appends a string such as `<2>' to get an unused name. See also 27.9 Creating Buffers.

Please note: create-file-buffer does not associate the new buffer with a file and does not select the buffer. It also does not use the default major mode.

(create-file-buffer "foo")
     => #<buffer foo>
(create-file-buffer "foo")
     => #<buffer foo<2>>
(create-file-buffer "foo")
     => #<buffer foo<3>>

This function is used by find-file-noselect. It uses generate-new-buffer (see section 27.9 Creating Buffers).

Function: after-find-file &optional error warn noauto after-find-file-from-revert-buffer nomodes
This function sets the buffer major mode, and parses local variables (see section 23.1.3 How Emacs Chooses a Major Mode). It is called by find-file-noselect and by the default revert function (see section 26.3 Reverting).

If reading the file got an error because the file does not exist, but its directory does exist, the caller should pass a non-nil value for error. In that case, after-find-file issues a warning: `(New file)'. For more serious errors, the caller should usually not call after-find-file.

If warn is non-nil, then this function issues a warning if an auto-save file exists and is more recent than the visited file.

If noauto is non-nil, that says not to enable or disable Auto-Save mode. The mode remains enabled if it was enabled before.

If after-find-file-from-revert-buffer is non-nil, that means this call was from revert-buffer. This has no direct effect, but some mode functions and hook functions check the value of this variable.

If nomodes is non-nil, that means don't alter the buffer's major mode, don't process local variables specifications in the file, and don't run find-file-hooks. This feature is used by revert-buffer in some cases.

The last thing after-find-file does is call all the functions in the list find-file-hooks.

[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [Top] [Contents] [Index] [ ? ]

25.2 Saving Buffers

When you edit a file in Emacs, you are actually working on a buffer that is visiting that file--that is, the contents of the file are copied into the buffer and the copy is what you edit. Changes to the buffer do not change the file until you save the buffer, which means copying the contents of the buffer into the file.

Command: save-buffer &optional backup-option
This function saves the contents of the current buffer in its visited file if the buffer has been modified since it was last visited or saved. Otherwise it does nothing.

save-buffer is responsible for making backup files. Normally, backup-option is nil, and save-buffer makes a backup file only if this is the first save since visiting the file. Other values for backup-option request the making of backup files in other circumstances:

Command: save-some-buffers &optional save-silently-p pred
This command saves some modified file-visiting buffers. Normally it asks the user about each buffer. But if save-silently-p is non-nil, it saves all the file-visiting buffers without querying the user.

The optional pred argument controls which buffers to ask about. If it is nil, that means to ask only about file-visiting buffers. If it is t, that means also offer to save certain other non-file buffers--those that have a non-nil buffer-local value of buffer-offer-save. (A user who says `yes' to saving a non-file buffer is asked to specify the file name to use.) The save-buffers-kill-emacs function passes the value t for pred.

If pred is neither t nor nil, then it should be a function of no arguments. It will be called in each buffer to decide whether to offer to save that buffer. If it returns a non-nil value in a certain buffer, that means do offer to save that buffer.

Command: write-file filename &optional confirm
This function writes the current buffer into file filename, makes the buffer visit that file, and marks it not modified. Then it renames the buffer based on filename, appending a string like `<2>' if necessary to make a unique buffer name. It does most of this work by calling set-visited-file-name (see section 27.4 Buffer File Name) and save-buffer.

If confirm is non-nil, that means to ask for confirmation before overwriting an existing file.

Saving a buffer runs several hooks. It also performs format conversion (see section 25.12 File Format Conversion), and may save text properties in "annotations" (see section 32.19.7 Saving Text Properties in Files).

Variable: write-file-hooks
The value of this variable is a list of functions to be called before writing out a buffer to its visited file. If one of them returns non-nil, the file is considered already written and the rest of the functions are not called, nor is the usual code for writing the file executed.

If a function in write-file-hooks returns non-nil, it is responsible for making a backup file (if that is appropriate). To do so, execute the following code:

(or buffer-backed-up (backup-buffer))

You might wish to save the file modes value returned by backup-buffer and use that to set the mode bits of the file that you write. This is what save-buffer normally does.

The hook functions in write-file-hooks are also responsible for encoding the data (if desired): they must choose a suitable coding system (see section 33.10.3 Coding Systems in Lisp), perform the encoding (see section 33.10.7 Explicit Encoding and Decoding), and set last-coding-system-used to the coding system that was used (see section 33.10.2 Encoding and I/O).

Do not make this variable buffer-local. To set up buffer-specific hook functions, use write-contents-hooks instead.

Even though this is not a normal hook, you can use add-hook and remove-hook to manipulate the list. See section 23.6 Hooks.

Variable: local-write-file-hooks
This works just like write-file-hooks, but it is intended to be made buffer-local in particular buffers, and used for hooks that pertain to the file name or the way the buffer contents were obtained.

The variable is marked as a permanent local, so that changing the major mode does not alter a buffer-local value. This is convenient for packages that read "file" contents in special ways, and set up hooks to save the data in a corresponding way.

Variable: write-contents-hooks
This works just like write-file-hooks, but it is intended for hooks that pertain to the contents of the file, as opposed to hooks that pertain to where the file came from. Such hooks are usually set up by major modes, as buffer-local bindings for this variable.

This variable automatically becomes buffer-local whenever it is set; switching to a new major mode always resets this variable. When you use add-hooks to add an element to this hook, you should not specify a non-nil local argument, since this variable is used only buffer-locally.

Variable: after-save-hook
This normal hook runs after a buffer has been saved in its visited file. One use of this hook is in Fast Lock mode; it uses this hook to save the highlighting information in a cache file.

Variable: file-precious-flag
If this variable is non-nil, then save-buffer protects against I/O errors while saving by writing the new file to a temporary name instead of the name it is supposed to have, and then renaming it to the intended name after it is clear there are no errors. This procedure prevents problems such as a lack of disk space from resulting in an invalid file.

As a side effect, backups are necessarily made by copying. See section 26.1.2 Backup by Renaming or by Copying?. Yet, at the same time, saving a precious file always breaks all hard links between the file you save and other file names.

Some modes give this variable a non-nil buffer-local value in particular buffers.

User Option: require-final-newline
This variable determines whether files may be written out that do not end with a newline. If the value of the variable is t, then save-buffer silently adds a newline at the end of the file whenever the buffer being saved does not already end in one. If the value of the variable is non-nil, but not t, then save-buffer asks the user whether to add a newline each time the case arises.

If the value of the variable is nil, then save-buffer doesn't add newlines at all. nil is the default value, but a few major modes set it to t in particular buffers.

See also the function set-visited-file-name (see section 27.4 Buffer File Name).

[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [Top] [Contents] [Index] [ ? ]

25.3 Reading from Files

You can copy a file from the disk and insert it into a buffer using the insert-file-contents function. Don't use the user-level command insert-file in a Lisp program, as that sets the mark.

Function: insert-file-contents filename &optional visit beg end replace
This function inserts the contents of file filename into the current buffer after point. It returns a list of the absolute file name and the length of the data inserted. An error is signaled if filename is not the name of a file that can be read.

The function insert-file-contents checks the file contents against the defined file formats, and converts the file contents if appropriate. See section 25.12 File Format Conversion. It also calls the functions in the list after-insert-file-functions; see 32.19.7 Saving Text Properties in Files. Normally, one of the functions in the after-insert-file-functions list determines the coding system (see section 33.10 Coding Systems) used for decoding the file's contents.

If visit is non-nil, this function additionally marks the buffer as unmodified and sets up various fields in the buffer so that it is visiting the file filename: these include the buffer's visited file name and its last save file modtime. This feature is used by find-file-noselect and you probably should not use it yourself.

If beg and end are non-nil, they should be integers specifying the portion of the file to insert. In this case, visit must be nil. For example,

(insert-file-contents filename nil 0 500)

inserts the first 500 characters of a file.

If the argument replace is non-nil, it means to replace the contents of the buffer (actually, just the accessible portion) with the contents of the file. This is better than simply deleting the buffer contents and inserting the whole file, because (1) it preserves some marker positions and (2) it puts less data in the undo list.

It is possible to read a special file (such as a FIFO or an I/O device) with insert-file-contents, as long as replace and visit are nil.

Function: insert-file-contents-literally filename &optional visit beg end replace
This function works like insert-file-contents except that it does not do format decoding (see section 25.12 File Format Conversion), does not do character code conversion (see section 33.10 Coding Systems), does not run find-file-hooks, does not perform automatic uncompression, and so on.

If you want to pass a file name to another process so that another program can read the file, use the function file-local-copy; see 25.11 Making Certain File Names "Magic".

[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [Top] [Contents] [Index] [ ? ]

25.4 Writing to Files

You can write the contents of a buffer, or part of a buffer, directly to a file on disk using the append-to-file and write-region functions. Don't use these functions to write to files that are being visited; that could cause confusion in the mechanisms for visiting.

Command: append-to-file start end filename
This function appends the contents of the region delimited by start and end in the current buffer to the end of file filename. If that file does not exist, it is created. This function returns nil.

An error is signaled if filename specifies a nonwritable file, or a nonexistent file in a directory where files cannot be created.

Command: write-region start end filename &optional append visit lockname mustbenew
This function writes the region delimited by start and end in the current buffer into the file specified by filename.

If start is a string, then write-region writes or appends that string, rather than text from the buffer. end is ignored in this case.

If append is non-nil, then the specified text is appended to the existing file contents (if any). Starting in Emacs 21, if append is an integer, then write-region seeks to that byte offset from the start of the file and writes the data from there.

If mustbenew is non-nil, then write-region asks for confirmation if filename names an existing file. Starting in Emacs 21, if mustbenew is the symbol excl, then write-region does not ask for confirmation, but instead it signals an error file-already-exists if the file already exists.

The test for an existing file, when mustbenew is excl, uses a special system feature. At least for files on a local disk, there is no chance that some other program could create a file of the same name before Emacs does, without Emacs's noticing.

If visit is t, then Emacs establishes an association between the buffer and the file: the buffer is then visiting that file. It also sets the last file modification time for the current buffer to filename's modtime, and marks the buffer as not modified. This feature is used by save-buffer, but you probably should not use it yourself.

If visit is a string, it specifies the file name to visit. This way, you can write the data to one file (filename) while recording the buffer as visiting another file (visit). The argument visit is used in the echo area message and also for file locking; visit is stored in buffer-file-name. This feature is used to implement file-precious-flag; don't use it yourself unless you really know what you're doing.

The optional argument lockname, if non-nil, specifies the file name to use for purposes of locking and unlocking, overriding filename and visit for that purpose.

The function write-region converts the data which it writes to the appropriate file formats specified by buffer-file-format. See section 25.12 File Format Conversion. It also calls the functions in the list write-region-annotate-functions; see 32.19.7 Saving Text Properties in Files.

Normally, write-region displays the message `Wrote filename' in the echo area. If visit is neither t nor nil nor a string, then this message is inhibited. This feature is useful for programs that use files for internal purposes, files that the user does not need to know about.

Macro: with-temp-file file body...
The with-temp-file macro evaluates the body forms with a temporary buffer as the current buffer; then, at the end, it writes the buffer contents into file file. It kills the temporary buffer when finished, restoring the buffer that was current before the with-temp-file form. Then it returns the value of the last form in body.

The current buffer is restored even in case of an abnormal exit via throw or error (see section 10.5 Nonlocal Exits).

See also with-temp-buffer in 27.2 The Current Buffer.

[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [Top] [Contents] [Index] [ ? ]

25.5 File Locks

When two users edit the same file at the same time, they are likely to interfere with each other. Emacs tries to prevent this situation from arising by recording a file lock when a file is being modified. Emacs can then detect the first attempt to modify a buffer visiting a file that is locked by another Emacs job, and ask the user what to do. The file lock is really a file, a symbolic link with a special name, stored in the same directory as the file you are editing.

When you access files using NFS, there may be a small probability that you and another user will both lock the same file "simultaneously". If this happens, it is possible for the two users to make changes simultaneously, but Emacs will still warn the user who saves second. Also, the detection of modification of a buffer visiting a file changed on disk catches some cases of simultaneous editing; see 27.6 Comparison of Modification Time.

Function: file-locked-p filename
This function returns nil if the file filename is not locked. It returns t if it is locked by this Emacs process, and it returns the name of the user who has locked it if it is locked by some other job.

(file-locked-p "foo")
     => nil

Function: lock-buffer &optional filename
This function locks the file filename, if the current buffer is modified. The argument filename defaults to the current buffer's visited file. Nothing is done if the current buffer is not visiting a file, or is not modified.

Function: unlock-buffer
This function unlocks the file being visited in the current buffer, if the buffer is modified. If the buffer is not modified, then the file should not be locked, so this function does nothing. It also does nothing if the current buffer is not visiting a file.

File locking is not supported on some systems. On systems that do not support it, the functions lock-buffer, unlock-buffer and file-locked-p do nothing and return nil.

Function: ask-user-about-lock file other-user
This function is called when the user tries to modify file, but it is locked by another user named other-user. The default definition of this function asks the user to say what to do. The value this function returns determines what Emacs does next:

If you wish, you can replace the ask-user-about-lock function with your own version that makes the decision in another way. The code for its usual definition is in `userlock.el'.

[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [Top] [Contents] [Index] [ ? ]

25.6 Information about Files

The functions described in this section all operate on strings that designate file names. All the functions have names that begin with the word `file'. These functions all return information about actual files or directories, so their arguments must all exist as actual files or directories unless otherwise noted.

25.6.1 Testing Accessibility  Is a given file readable? Writable?
25.6.2 Distinguishing Kinds of Files  Is it a directory? A symbolic link?
25.6.3 Truenames  Eliminating symbolic links from a file name.
25.6.4 Other Information about Files  How large is it? Any other names? Etc.

[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [Top] [Contents] [Index] [ ? ]

25.6.1 Testing Accessibility

These functions test for permission to access a file in specific ways.

Function: file-exists-p filename
This function returns t if a file named filename appears to exist. This does not mean you can necessarily read the file, only that you can find out its attributes. (On Unix and GNU/Linux, this is true if the file exists and you have execute permission on the containing directories, regardless of the protection of the file itself.)

If the file does not exist, or if fascist access control policies prevent you from finding the attributes of the file, this function returns nil.

Function: file-readable-p filename
This function returns t if a file named filename exists and you can read it. It returns nil otherwise.

(file-readable-p "files.texi")
     => t
(file-exists-p "/usr/spool/mqueue")
     => t
(file-readable-p "/usr/spool/mqueue")
     => nil

Function: file-executable-p filename
This function returns t if a file named filename exists and you can execute it. It returns nil otherwise. On Unix and GNU/Linux, if the file is a directory, execute permission means you can check the existence and attributes of files inside the directory, and open those files if their modes permit.

Function: file-writable-p filename
This function returns t if the file filename can be written or created by you, and nil otherwise. A file is writable if the file exists and you can write it. It is creatable if it does not exist, but the specified directory does exist and you can write in that directory.

In the third example below, `foo' is not writable because the parent directory does not exist, even though the user could create such a directory.

(file-writable-p "~/foo")
     => t
(file-writable-p "/foo")
     => nil
(file-writable-p "~/no-such-dir/foo")
     => nil

Function: file-accessible-directory-p dirname
This function returns t if you have permission to open existing files in the directory whose name as a file is dirname; otherwise (or if there is no such directory), it returns nil. The value of dirname may be either a directory name or the file name of a file which is a directory.

Example: after the following,

(file-accessible-directory-p "/foo")
     => nil

we can deduce that any attempt to read a file in `/foo/' will give an error.

Function: access-file filename string
This function opens file filename for reading, then closes it and returns nil. However, if the open fails, it signals an error using string as the error message text.

Function: file-ownership-preserved-p filename
This function returns t if deleting the file filename and then creating it anew would keep the file's owner unchanged.

Function: file-newer-than-file-p filename1 filename2
This function returns t if the file filename1 is newer than file filename2. If filename1 does not exist, it returns nil. If filename2 does not exist, it returns t.

In the following example, assume that the file `aug-19' was written on the 19th, `aug-20' was written on the 20th, and the file `no-file' doesn't exist at all.

(file-newer-than-file-p "aug-19" "aug-20")
     => nil
(file-newer-than-file-p "aug-20" "aug-19")
     => t
(file-newer-than-file-p "aug-19" "no-file")
     => t
(file-newer-than-file-p "no-file" "aug-19")
     => nil

You can use file-attributes to get a file's last modification time as a list of two numbers. See section 25.6.4 Other Information about Files.

[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [Top] [Contents] [Index] [ ? ]

25.6.2 Distinguishing Kinds of Files

This section describes how to distinguish various kinds of files, such as directories, symbolic links, and ordinary files.

Function: file-symlink-p filename
If the file filename is a symbolic link, the file-symlink-p function returns the file name to which it is linked. This may be the name of a text file, a directory, or even another symbolic link, or it may be a nonexistent file name.

If the file filename is not a symbolic link (or there is no such file), file-symlink-p returns nil.

(file-symlink-p "foo")
     => nil
(file-symlink-p "sym-link")
     => "foo"
(file-symlink-p "sym-link2")
     => "sym-link"
(file-symlink-p "/bin")
     => "/pub/bin"

Function: file-directory-p filename
This function returns t if filename is the name of an existing directory, nil otherwise.

(file-directory-p "~rms")
     => t
(file-directory-p "~rms/lewis/files.texi")
     => nil
(file-directory-p "~rms/lewis/no-such-file")
     => nil
(file-directory-p "$HOME")
     => nil
 (substitute-in-file-name "$HOME"))
     => t

Function: file-regular-p filename
This function returns t if the file filename exists and is a regular file (not a directory, named pipe, terminal, or other I/O device).

[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [Top] [Contents] [Index] [ ? ]

25.6.3 Truenames

The truename of a file is the name that you get by following symbolic links at all levels until none remain, then simplifying away `.' and `..' appearing as name components. This results in a sort of canonical name for the file. A file does not always have a unique truename; the number of distinct truenames a file has is equal to the number of hard links to the file. However, truenames are useful because they eliminate symbolic links as a cause of name variation.

Function: file-truename filename
The function file-truename returns the truename of the file filename. The argument must be an absolute file name.

Function: file-chase-links filename
This function follows symbolic links, starting with filename, until it finds a file name which is not the name of a symbolic link. Then it returns that file name.

To illustrate the difference between file-chase-links and file-truename, suppose that `/usr/foo' is a symbolic link to the directory `/home/foo', and `/home/foo/hello' is an ordinary file (or at least, not a symbolic link) or nonexistent. Then we would have:

(file-chase-links "/usr/foo/hello")
     ;; This does not follow the links in the parent directories.
     => "/usr/foo/hello"
(file-truename "/usr/foo/hello")
     ;; Assuming that `/home' is not a symbolic link.
     => "/home/foo/hello"

See section 27.4 Buffer File Name, for related information.

[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [Top] [Contents] [Index] [ ? ]

25.6.4 Other Information about Files

This section describes the functions for getting detailed information about a file, other than its contents. This information includes the mode bits that control access permission, the owner and group numbers, the number of names, the inode number, the size, and the times of access and modification.

Function: file-modes filename
This function returns the mode bits of filename, as an integer. The mode bits are also called the file permissions, and they specify access control in the usual Unix fashion. If the low-order bit is 1, then the file is executable by all users, if the second-lowest-order bit is 1, then the file is writable by all users, etc.

The highest value returnable is 4095 (7777 octal), meaning that everyone has read, write, and execute permission, that the SUID bit is set for both others and group, and that the sticky bit is set.

(file-modes "~/junk/diffs")
     => 492               ; Decimal integer.
(format "%o" 492)
     => "754"             ; Convert to octal.

(set-file-modes "~/junk/diffs" 438)
     => nil

(format "%o" 438)
     => "666"             ; Convert to octal.

% ls -l diffs
  -rw-rw-rw-  1 lewis 0 3063 Oct 30 16:00 diffs

Function: file-nlinks filename
This functions returns the number of names (i.e., hard links) that file filename has. If the file does not exist, then this function returns nil. Note that symbolic links have no effect on this function, because they are not considered to be names of the files they link to.

% ls -l foo*
-rw-rw-rw-  2 rms       4 Aug 19 01:27 foo
-rw-rw-rw-  2 rms       4 Aug 19 01:27 foo1

(file-nlinks "foo")
     => 2
(file-nlinks "doesnt-exist")
     => nil

Function: file-attributes filename
This function returns a list of attributes of file filename. If the specified file cannot be opened, it returns nil.

The elements of the list, in order, are:

  1. t for a directory, a string for a symbolic link (the name linked to), or nil for a text file.

  2. The number of names the file has. Alternate names, also known as hard links, can be created by using the add-name-to-file function (see section 25.7 Changing File Names and Attributes).

  3. The file's UID.

  4. The file's GID.

  5. The time of last access, as a list of two integers. The first integer has the high-order 16 bits of time, the second has the low 16 bits. (This is similar to the value of current-time; see 40.5 Time of Day.)

  6. The time of last modification as a list of two integers (as above).

  7. The time of last status change as a list of two integers (as above).

  8. The size of the file in bytes. If the size is too large to fit in a Lisp integer, this is a floating point number.

  9. The file's modes, as a string of ten letters or dashes, as in `ls -l'.

  10. t if the file's GID would change if file were deleted and recreated; nil otherwise.

  11. The file's inode number. If possible, this is an integer. If the inode number is too large to be represented as an integer in Emacs Lisp, then the value has the form (high . low), where low holds the low 16 bits.

  12. The file system number of the file system that the file is in. Depending on the magnitude of the value, this can be either an integer or a cons cell, in the same manner as the inode number. This element and the file's inode number together give enough information to distinguish any two files on the system--no two files can have the same values for both of these numbers.

For example, here are the file attributes for `files.texi':

(file-attributes "files.texi")
     =>  (nil 1 2235 75 
          (8489 20284) 
          (8489 20284) 
          (8489 20285)
          14906 "-rw-rw-rw-" 
          nil 129500 -32252)

and here is how the result is interpreted:

is neither a directory nor a symbolic link.

has only one name (the name `files.texi' in the current default directory).

is owned by the user with UID 2235.

is in the group with GID 75.

(8489 20284)
was last accessed on Aug 19 00:09.

(8489 20284)
was last modified on Aug 19 00:09.

(8489 20285)
last had its inode changed on Aug 19 00:09.

is 14906 bytes long. (It may not contain 14906 characters, though, if some of the bytes belong to multibyte sequences.)

has a mode of read and write access for the owner, group, and world.

would retain the same GID if it were recreated.

has an inode number of 129500.
is on file system number -32252.

[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [Top] [Contents] [Index] [ ? ]

25.7 Changing File Names and Attributes

The functions in this section rename, copy, delete, link, and set the modes of files.

In the functions that have an argument newname, if a file by the name of newname already exists, the actions taken depend on the value of the argument ok-if-already-exists:

Function: add-name-to-file oldname newname &optional ok-if-already-exists
This function gives the file named oldname the additional name newname. This means that newname becomes a new "hard link" to oldname.

In the first part of the following example, we list two files, `foo' and `foo3'.

% ls -li fo*
81908 -rw-rw-rw-  1 rms       29 Aug 18 20:32 foo
84302 -rw-rw-rw-  1 rms       24 Aug 18 20:31 foo3

Now we create a hard link, by calling add-name-to-file, then list the files again. This shows two names for one file, `foo' and `foo2'.

(add-name-to-file "foo" "foo2")
     => nil

% ls -li fo*
81908 -rw-rw-rw-  2 rms       29 Aug 18 20:32 foo
81908 -rw-rw-rw-  2 rms       29 Aug 18 20:32 foo2
84302 -rw-rw-rw-  1 rms       24 Aug 18 20:31 foo3

Finally, we evaluate the following:

(add-name-to-file "foo" "foo3" t)

and list the files again. Now there are three names for one file: `foo', `foo2', and `foo3'. The old contents of `foo3' are lost.

(add-name-to-file "foo1" "foo3")
     => nil

% ls -li fo*
81908 -rw-rw-rw-  3 rms       29 Aug 18 20:32 foo
81908 -rw-rw-rw-  3 rms       29 Aug 18 20:32 foo2
81908 -rw-rw-rw-  3 rms       29 Aug 18 20:32 foo3

This function is meaningless on operating systems where multiple names for one file are not allowed. Some systems implement multiple names by copying the file instead.

See also file-nlinks in 25.6.4 Other Information about Files.

Command: rename-file filename newname &optional ok-if-already-exists
This command renames the file filename as newname.

If filename has additional names aside from filename, it continues to have those names. In fact, adding the name newname with add-name-to-file and then deleting filename has the same effect as renaming, aside from momentary intermediate states.

In an interactive call, this function prompts for filename and newname in the minibuffer; also, it requests confirmation if newname already exists.

Command: copy-file oldname newname &optional ok-if-exists time
This command copies the file oldname to newname. An error is signaled if oldname does not exist.

If time is non-nil, then this function gives the new file the same last-modified time that the old one has. (This works on only some operating systems.) If setting the time gets an error, copy-file signals a file-date-error error.

In an interactive call, this function prompts for filename and newname in the minibuffer; also, it requests confirmation if newname already exists.

Command: delete-file filename
This command deletes the file filename, like the shell command `rm filename'. If the file has multiple names, it continues to exist under the other names.

A suitable kind of file-error error is signaled if the file does not exist, or is not deletable. (On Unix and GNU/Linux, a file is deletable if its directory is writable.)

See also delete-directory in 25.10 Creating and Deleting Directories.

Command: make-symbolic-link filename newname &optional ok-if-exists
This command makes a symbolic link to filename, named newname. This is like the shell command `ln -s filename newname'.

In an interactive call, this function prompts for filename and newname in the minibuffer; also, it requests confirmation if newname already exists.

This function is not available on systems that don't support symbolic links.

Function: define-logical-name varname string
This function defines the logical name name to have the value string. It is available only on VMS.

Function: set-file-modes filename mode
This function sets mode bits of filename to mode (which must be an integer). Only the low 12 bits of mode are used.

Function: set-default-file-modes mode
This function sets the default file protection for new files created by Emacs and its subprocesses. Every file created with Emacs initially has this protection, or a subset of it (write-region will not give a file execute permission even if the default file protection allows execute permission). On Unix and GNU/Linux, the default protection is the bitwise complement of the "umask" value.

The argument mode must be an integer. On most systems, only the low 9 bits of mode are meaningful. You can use the Lisp construct for octal character codes to enter mode; for example,

(set-default-file-modes ?\644)

Saving a modified version of an existing file does not count as creating the file; it preserves the existing file's mode, whatever that is. So the default file protection has no effect.

Function: default-file-modes
This function returns the current default protection value.

On MS-DOS, there is no such thing as an "executable" file mode bit. So Emacs considers a file executable if its name ends in one of the standard executable extensions, such as `.com', `.bat', `.exe', and some others. Files that begin with the Unix-standard `#!' signature, such as shell and Perl scripts, are also considered as executable files. This is reflected in the values returned by file-modes and file-attributes. Directories are also reported with executable bit set, for compatibility with Unix.

[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [Top] [Contents] [Index] [ ? ]

25.8 File Names

Files are generally referred to by their names, in Emacs as elsewhere. File names in Emacs are represented as strings. The functions that operate on a file all expect a file name argument.

In addition to operating on files themselves, Emacs Lisp programs often need to operate on file names; i.e., to take them apart and to use part of a name to construct related file names. This section describes how to manipulate file names.

The functions in this section do not actually access files, so they can operate on file names that do not refer to an existing file or directory.

On MS-DOS and MS-Windows, these functions (like the function that actually operate on files) accept MS-DOS or MS-Windows file-name syntax, where backslashes separate the components, as well as Unix syntax; but they always return Unix syntax. On VMS, these functions (and the ones that operate on files) understand both VMS file-name syntax and Unix syntax. This enables Lisp programs to specify file names in Unix syntax and work properly on all systems without change.

25.8.1 File Name Components  The directory part of a file name, and the rest.
25.8.2 Directory Names  A directory's name as a directory is different from its name as a file.
25.8.3 Absolute and Relative File Names  Some file names are relative to a current directory.
25.8.4 Functions that Expand Filenames  Converting relative file names to absolute ones.
25.8.5 Generating Unique File Names  Generating names for temporary files.
25.8.6 File Name Completion  Finding the completions for a given file name.
25.8.7 Standard File Names  If your package uses a fixed file name, how to handle various operating systems simply.

[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [Top] [Contents] [Index] [ ? ]

25.8.1 File Name Components

The operating system groups files into directories. To specify a file, you must specify the directory and the file's name within that directory. Therefore, Emacs considers a file name as having two main parts: the directory name part, and the nondirectory part (or file name within the directory). Either part may be empty. Concatenating these two parts reproduces the original file name.

On most systems, the directory part is everything up to and including the last slash (backslash is also allowed in input on MS-DOS or MS-Windows); the nondirectory part is the rest. The rules in VMS syntax are complicated.

For some purposes, the nondirectory part is further subdivided into the name proper and the version number. On most systems, only backup files have version numbers in their names. On VMS, every file has a version number, but most of the time the file name actually used in Emacs omits the version number, so that version numbers in Emacs are found mostly in directory lists.

Function: file-name-directory filename
This function returns the directory part of filename (or nil if filename does not include a directory part). On most systems, the function returns a string ending in a slash. On VMS, it returns a string ending in one of the three characters `:', `]', or `>'.

(file-name-directory "lewis/foo")  ; Unix example
     => "lewis/"
(file-name-directory "foo")        ; Unix example
     => nil
(file-name-directory "[X]FOO.TMP") ; VMS example
     => "[X]"

Function: file-name-nondirectory filename
This function returns the nondirectory part of filename.

(file-name-nondirectory "lewis/foo")
     => "foo"
(file-name-nondirectory "foo")
     => "foo"
;; The following example is accurate only on VMS.
(file-name-nondirectory "[X]FOO.TMP")
     => "FOO.TMP"

Function: file-name-sans-versions filename &optional keep-backup-version
This function returns filename with any file version numbers, backup version numbers, or trailing tildes discarded.

If keep-backup-version is non-nil, then true file version numbers understood as such by the file system are discarded from the return value, but backup version numbers are kept.

(file-name-sans-versions "~rms/foo.~1~")
     => "~rms/foo"
(file-name-sans-versions "~rms/foo~")
     => "~rms/foo"
(file-name-sans-versions "~rms/foo")
     => "~rms/foo"
;; The following example applies to VMS only.
(file-name-sans-versions "foo;23")
     => "foo"

Function: file-name-sans-extension filename
This function returns filename minus its "extension," if any. The extension, in a file name, is the part that starts with the last `.' in the last name component. For example,

(file-name-sans-extension "foo.lose.c")
     => "foo.lose"
(file-name-sans-extension "big.hack/foo")
     => "big.hack/foo"

Function: file-name-extension filename &optional period
This function returns filename's final "extension," if any, after applying file-name-sans-versions to remove any version/backup part. If period is non-nil, then the returned value includes the period that delimits the extension, and if filename has no extension, the value is "".

[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [Top] [Contents] [Index] [ ? ]

25.8.2 Directory Names

A directory name is the name of a directory. A directory is a kind of file, and it has a file name, which is related to the directory name but not identical to it. (This is not quite the same as the usual Unix terminology.) These two different names for the same entity are related by a syntactic transformation. On most systems, this is simple: a directory name ends in a slash (or backslash), whereas the directory's name as a file lacks that slash. On VMS, the relationship is more complicated.

The difference between a directory name and its name as a file is subtle but crucial. When an Emacs variable or function argument is described as being a directory name, a file name of a directory is not acceptable.

The following two functions convert between directory names and file names. They do nothing special with environment variable substitutions such as `$HOME', and the constructs `~', and `..'.

Function: file-name-as-directory filename
This function returns a string representing filename in a form that the operating system will interpret as the name of a directory. On most systems, this means appending a slash to the string (if it does not already end in one). On VMS, the function converts a string of the form `[X]Y.DIR.1' to the form `[X.Y]'.

(file-name-as-directory "~rms/lewis")
     => "~rms/lewis/"

Function: directory-file-name dirname
This function returns a string representing dirname in a form that the operating system will interpret as the name of a file. On most systems, this means removing the final slash (or backslash) from the string. On VMS, the function converts a string of the form `[X.Y]' to `[X]Y.DIR.1'.

(directory-file-name "~lewis/")
     => "~lewis"

Directory name abbreviations are useful for directories that are normally accessed through symbolic links. Sometimes the users recognize primarily the link's name as "the name" of the directory, and find it annoying to see the directory's "real" name. If you define the link name as an abbreviation for the "real" name, Emacs shows users the abbreviation instead.

Variable: directory-abbrev-alist
The variable directory-abbrev-alist contains an alist of abbreviations to use for file directories. Each element has the form (from . to), and says to replace from with to when it appears in a directory name. The from string is actually a regular expression; it should always start with `^'. The function abbreviate-file-name performs these substitutions.

You can set this variable in `site-init.el' to describe the abbreviations appropriate for your site.

Here's an example, from a system on which file system `/home/fsf' and so on are normally accessed through symbolic links named `/fsf' and so on.

(("^/home/fsf" . "/fsf")
 ("^/home/gp" . "/gp")
 ("^/home/gd" . "/gd"))

To convert a directory name to its abbreviation, use this function:

Function: abbreviate-file-name dirname
This function applies abbreviations from directory-abbrev-alist to its argument, and substitutes `~' for the user's home directory.

[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [Top] [Contents] [Index] [ ? ]

25.8.3 Absolute and Relative File Names

All the directories in the file system form a tree starting at the root directory. A file name can specify all the directory names starting from the root of the tree; then it is called an absolute file name. Or it can specify the position of the file in the tree relative to a default directory; then it is called a relative file name. On Unix and GNU/Linux, an absolute file name starts with a slash or a tilde (`~'), and a relative one does not. On MS-DOS and MS-Windows, an absolute file name starts with a slash or a backslash, or with a drive specification `x:/', where x is the drive letter. The rules on VMS are complicated.

Function: file-name-absolute-p filename
This function returns t if file filename is an absolute file name, nil otherwise. On VMS, this function understands both Unix syntax and VMS syntax.

(file-name-absolute-p "~rms/foo")
     => t
(file-name-absolute-p "rms/foo")
     => nil
(file-name-absolute-p "/user/rms/foo")
     => t

[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [Top] [Contents] [Index] [ ? ]

25.8.4 Functions that Expand Filenames

Expansion of a file name means converting a relative file name to an absolute one. Since this is done relative to a default directory, you must specify the default directory name as well as the file name to be expanded. Expansion also simplifies file names by eliminating redundancies such as `./' and `name/../'.

Function: expand-file-name filename &optional directory
This function converts filename to an absolute file name. If directory is supplied, it is the default directory to start with if filename is relative. (The value of directory should itself be an absolute directory name; it may start with `~'.) Otherwise, the current buffer's value of default-directory is used. For example:

(expand-file-name "foo")
     => "/xcssun/users/rms/lewis/foo"
(expand-file-name "../foo")
     => "/xcssun/users/rms/foo"
(expand-file-name "foo" "/usr/spool/")
     => "/usr/spool/foo"
(expand-file-name "$HOME/foo")
     => "/xcssun/users/rms/lewis/$HOME/foo"

Filenames containing `.' or `..' are simplified to their canonical form:

(expand-file-name "bar/../foo")
     => "/xcssun/users/rms/lewis/foo"

Note that expand-file-name does not expand environment variables; only substitute-in-file-name does that.

Function: file-relative-name filename &optional directory
This function does the inverse of expansion--it tries to return a relative name that is equivalent to filename when interpreted relative to directory. If directory is omitted or nil, it defaults to the current buffer's default directory.

On some operating systems, an absolute file name begins with a device name. On such systems, filename has no relative equivalent based on directory if they start with two different device names. In this case, file-relative-name returns filename in absolute form.

(file-relative-name "/foo/bar" "/foo/")
     => "bar"
(file-relative-name "/foo/bar" "/hack/")
     => "../foo/bar"

Variable: default-directory
The value of this buffer-local variable is the default directory for the current buffer. It should be an absolute directory name; it may start with `~'. This variable is buffer-local in every buffer.

expand-file-name uses the default directory when its second argument is nil.

Aside from VMS, the value is always a string ending with a slash.

     => "/user/lewis/manual/"

Function: substitute-in-file-name filename
This function replaces environment variables references in filename with the environment variable values. Following standard Unix shell syntax, `$' is the prefix to substitute an environment variable value.

The environment variable name is the series of alphanumeric characters (including underscores) that follow the `$'. If the character following the `$' is a `{', then the variable name is everything up to the matching `}'.

Here we assume that the environment variable HOME, which holds the user's home directory name, has value `/xcssun/users/rms'.

(substitute-in-file-name "$HOME/foo")
     => "/xcssun/users/rms/foo"

After substitution, if a `~' or a `/' appears following a `/', everything before the following `/' is discarded:

(substitute-in-file-name "bar/~/foo")
     => "~/foo"
(substitute-in-file-name "/usr/local/$HOME/foo")
     => "/xcssun/users/rms/foo"
     ;; `/usr/local/' has been discarded.

On VMS, `$' substitution is not done, so this function does nothing on VMS except discard superfluous initial components as shown above.

[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [Top] [Contents] [Index] [ ? ]

25.8.5 Generating Unique File Names

Some programs need to write temporary files. Here is the usual way to construct a name for such a file, starting in Emacs 21:

(make-temp-file name-of-application)

The job of make-temp-file is to prevent two different users or two different jobs from trying to use the exact same file name.

Function: make-temp-file prefix &optional dir-flag
This function creates a temporary file and returns its name. The name starts with prefix; it also contains a number that is different in each Emacs job. If prefix is a relative file name, it is expanded against temporary-file-directory.

(make-temp-file "foo")
     => "/tmp/foo232J6v"

When make-temp-file returns, the file has been created and is empty. At that point, you should write the intended contents into the file.

If dir-flag is non-nil, make-temp-file creates an empty directory instead of an empty file.

To prevent conflicts among different libraries running in the same Emacs, each Lisp program that uses make-temp-file should have its own prefix. The number added to the end of prefix distinguishes between the same application running in different Emacs jobs. Additional added characters permit a large number of distinct names even in one Emacs job.

The default directory for temporary files is controlled by the variable temporary-file-directory. This variable gives the user a uniform way to specify the directory for all temporary files. Some programs use small-temporary-file-directory instead, if that is non-nil. To use it, you should expand the prefix against the proper directory before calling make-temp-file.

In older Emacs versions where make-temp-file does not exist, you should use make-temp-name instead:

 (expand-file-name name-of-application

Function: make-temp-name string
This function generates a string that can be used as a unique file name. The name starts with string, and contains a number that is different in each Emacs job. It is like make-temp-file except that it just constructs a name, and does not create a file. On MS-DOS, the string prefix can be truncated to fit into the 8+3 file-name limits.

Variable: temporary-file-directory
This variable specifies the directory name for creating temporary files. Its value should be a directory name (see section 25.8.2 Directory Names), but it is good for Lisp programs to cope if the value is a directory's file name instead. Using the value as the second argument to expand-file-name is a good way to achieve that.

The default value is determined in a reasonable way for your operating system; it is based on the TMPDIR, TMP and TEMP environment variables, with a fall-back to a system-dependent name if none of these variables is defined.

Even if you do not use make-temp-name to choose the temporary file's name, you should still use this variable to decide which directory to put the file in. However, if you expect the file to be small, you should use small-temporary-file-directory first if that is non-nil.

Variable: small-temporary-file-directory
This variable (new in Emacs 21) specifies the directory name for creating certain temporary files, which are likely to be small.

If you want to write a temporary file which is likely to be small, you should compute the directory like this:

  (expand-file-name prefix
                    (or small-temporary-file-directory

[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [Top] [Contents] [Index] [ ? ]

25.8.6 File Name Completion

This section describes low-level subroutines for completing a file name. For other completion functions, see 20.5 Completion.

Function: file-name-all-completions partial-filename directory
This function returns a list of all possible completions for a file whose name starts with partial-filename in directory directory. The order of the completions is the order of the files in the directory, which is unpredictable and conveys no useful information.

The argument partial-filename must be a file name containing no directory part and no slash (or backslash on some systems). The current buffer's default directory is prepended to directory, if directory is not absolute.

In the following example, suppose that `~rms/lewis' is the current default directory, and has five files whose names begin with `f': `foo', `file~', `file.c', `file.c.~1~', and `file.c.~2~'.

(file-name-all-completions "f" "")
     => ("foo" "file~" "file.c.~2~" 
                "file.c.~1~" "file.c")

(file-name-all-completions "fo" "")  
     => ("foo")

Function: file-name-completion filename directory
This function completes the file name filename in directory directory. It returns the longest prefix common to all file names in directory directory that start with filename.

If only one match exists and filename matches it exactly, the function returns t. The function returns nil if directory directory contains no name starting with filename.

In the following example, suppose that the current default directory has five files whose names begin with `f': `foo', `file~', `file.c', `file.c.~1~', and `file.c.~2~'.

(file-name-completion "fi" "")
     => "file"

(file-name-completion "file.c.~1" "")
     => "file.c.~1~"

(file-name-completion "file.c.~1~" "")
     => t

(file-name-completion "file.c.~3" "")
     => nil

User Option: completion-ignored-extensions
file-name-completion usually ignores file names that end in any string in this list. It does not ignore them when all the possible completions end in one of these suffixes or when a buffer showing all possible completions is displayed.

A typical value might look like this:

     => (".o" ".elc" "~" ".dvi")

[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [Top] [Contents] [Index] [ ? ]

25.8.7 Standard File Names

Most of the file names used in Lisp programs are entered by the user. But occasionally a Lisp program needs to specify a standard file name for a particular use--typically, to hold customization information about each user. For example, abbrev definitions are stored (by default) in the file `~/.abbrev_defs'; the completion package stores completions in the file `~/.completions'. These are two of the many standard file names used by parts of Emacs for certain purposes.

Various operating systems have their own conventions for valid file names and for which file names to use for user profile data. A Lisp program which reads a file using a standard file name ought to use, on each type of system, a file name suitable for that system. The function convert-standard-filename makes this easy to do.

Function: convert-standard-filename filename
This function alters the file name filename to fit the conventions of the operating system in use, and returns the result as a new string.

The recommended way to specify a standard file name in a Lisp program is to choose a name which fits the conventions of GNU and Unix systems, usually with a nondirectory part that starts with a period, and pass it to convert-standard-filename instead of using it directly. Here is an example from the completion package:

(defvar save-completions-file-name
        (convert-standard-filename "~/.completions")
  "*The file name to save completions to.")

On GNU and Unix systems, and on some other systems as well, convert-standard-filename returns its argument unchanged. On some other systems, it alters the name to fit the system's conventions.

For example, on MS-DOS the alterations made by this function include converting a leading `.' to `_', converting a `_' in the middle of the name to `.' if there is no other `.', inserting a `.' after eight characters if there is none, and truncating to three characters after the `.'. (It makes other changes as well.) Thus, `.abbrev_defs' becomes `_abbrev.def', and `.completions' becomes `_complet.ion'.

[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [Top] [Contents] [Index] [ ? ]

25.9 Contents of Directories

A directory is a kind of file that contains other files entered under various names. Directories are a feature of the file system.

Emacs can list the names of the files in a directory as a Lisp list, or display the names in a buffer using the ls shell command. In the latter case, it can optionally display information about each file, depending on the options passed to the ls command.

Function: directory-files directory &optional full-name match-regexp nosort
This function returns a list of the names of the files in the directory directory. By default, the list is in alphabetical order.

If full-name is non-nil, the function returns the files' absolute file names. Otherwise, it returns the names relative to the specified directory.

If match-regexp is non-nil, this function returns only those file names that contain a match for that regular expression--the other file names are excluded from the list.

If nosort is non-nil, directory-files does not sort the list, so you get the file names in no particular order. Use this if you want the utmost possible speed and don't care what order the files are processed in. If the order of processing is visible to the user, then the user will probably be happier if you do sort the names.

(directory-files "~lewis")
     => ("#foo#" "#foo.el#" "." ".."
         "dired-mods.el" "files.texi" 

An error is signaled if directory is not the name of a directory that can be read.

Function: file-name-all-versions file dirname
This function returns a list of all versions of the file named file in directory dirname.

Function: file-expand-wildcards pattern &optional full
This function expands the wildcard pattern pattern, returning a list of file names that match it.

If pattern is written as an absolute file name, the values are absolute also.

If pattern is written as a relative file name, it is interpreted relative to the current default directory. The file names returned are normally also relative to the current default directory. However, if full is non-nil, they are absolute.

Function: insert-directory file switches &optional wildcard full-directory-p
This function inserts (in the current buffer) a directory listing for directory file, formatted with ls according to switches. It leaves point after the inserted text.

The argument file may be either a directory name or a file specification including wildcard characters. If wildcard is non-nil, that means treat file as a file specification with wildcards.

If full-directory-p is non-nil, that means the directory listing is expected to show the full contents of a directory. You should specify t when file is a directory and switches do not contain `-d'. (The `-d' option to ls says to describe a directory itself as a file, rather than showing its contents.)

On most systems, this function works by running a directory listing program whose name is in the variable insert-directory-program. If wildcard is non-nil, it also runs the shell specified by shell-file-name, to expand the wildcards.

MS-DOS and MS-Windows systems usually lack the standard Unix program ls, so this function emulates the standard Unix program ls with Lisp code.

Variable: insert-directory-program
This variable's value is the program to run to generate a directory listing for the function insert-directory. It is ignored on systems which generate the listing with Lisp code.

[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [Top] [Contents] [Index] [ ? ]

25.10 Creating and Deleting Directories

Most Emacs Lisp file-manipulation functions get errors when used on files that are directories. For example, you cannot delete a directory with delete-file. These special functions exist to create and delete directories.

Function: make-directory dirname &optional parents
This function creates a directory named dirname. If parents is non-nil, that means to create the parent directories first, if they don't already exist.

Function: delete-directory dirname
This function deletes the directory named dirname. The function delete-file does not work for files that are directories; you must use delete-directory for them. If the directory contains any files, delete-directory signals an error.

[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [Top] [Contents] [Index] [ ? ]

25.11 Making Certain File Names "Magic"

You can implement special handling for certain file names. This is called making those names magic. The principal use for this feature is in implementing remote file names (see section `Remote Files' in The GNU Emacs Manual).

To define a kind of magic file name, you must supply a regular expression to define the class of names (all those that match the regular expression), plus a handler that implements all the primitive Emacs file operations for file names that do match.

The variable file-name-handler-alist holds a list of handlers, together with regular expressions that determine when to apply each handler. Each element has this form:

(regexp . handler)

All the Emacs primitives for file access and file name transformation check the given file name against file-name-handler-alist. If the file name matches regexp, the primitives handle that file by calling handler.

The first argument given to handler is the name of the primitive; the remaining arguments are the arguments that were passed to that primitive. (The first of these arguments is most often the file name itself.) For example, if you do this:

(file-exists-p filename)

and filename has handler handler, then handler is called like this:

(funcall handler 'file-exists-p filename)

When a function takes two or more arguments that must be file names, it checks each of those names for a handler. For example, if you do this:

(expand-file-name filename dirname)

then it checks for a handler for filename and then for a handler for dirname. In either case, the handler is called like this:

(funcall handler 'expand-file-name filename dirname)

The handler then needs to figure out whether to handle filename or dirname.

Here are the operations that a magic file name handler gets to handle:

add-name-to-file, copy-file, delete-directory, delete-file, diff-latest-backup-file, directory-file-name, directory-files, dired-call-process, dired-compress-file, dired-uncache, expand-file-name, file-accessible-directory-p,
file-attributes, file-directory-p, file-executable-p, file-exists-p,
file-local-copy, file-modes, file-name-all-completions,
file-name-as-directory, file-name-completion, file-name-directory, file-name-nondirectory, file-name-sans-versions, file-newer-than-file-p, file-ownership-preserved-p, file-readable-p, file-regular-p, file-symlink-p, file-truename, file-writable-p, find-backup-file-name, get-file-buffer,
insert-directory, insert-file-contents, load, make-directory, make-symbolic-link, rename-file, set-file-modes, set-visited-file-modtime, shell-command,
unhandled-file-name-directory, vc-registered, verify-visited-file-modtime,

Handlers for insert-file-contents typically need to clear the buffer's modified flag, with (set-buffer-modified-p nil), if the visit argument is non-nil. This also has the effect of unlocking the buffer if it is locked.

The handler function must handle all of the above operations, and possibly others to be added in the future. It need not implement all these operations itself--when it has nothing special to do for a certain operation, it can reinvoke the primitive, to handle the operation "in the usual way". It should always reinvoke the primitive for an operation it does not recognize. Here's one way to do this:

(defun my-file-handler (operation &rest args)
  ;; First check for the specific operations
  ;; that we have special handling for.
  (cond ((eq operation 'insert-file-contents) ...)
        ((eq operation 'write-region) ...)
        ;; Handle any operation we don't know about.
        (t (let ((inhibit-file-name-handlers
                  (cons 'my-file-handler 
                        (and (eq inhibit-file-name-operation operation)
                 (inhibit-file-name-operation operation))
             (apply operation args)))))

When a handler function decides to call the ordinary Emacs primitive for the operation at hand, it needs to prevent the primitive from calling the same handler once again, thus leading to an infinite recursion. The example above shows how to do this, with the variables inhibit-file-name-handlers and inhibit-file-name-operation. Be careful to use them exactly as shown above; the details are crucial for proper behavior in the case of multiple handlers, and for operations that have two file names that may each have handlers.

Variable: inhibit-file-name-handlers
This variable holds a list of handlers whose use is presently inhibited for a certain operation.

Variable: inhibit-file-name-operation
The operation for which certain handlers are presently inhibited.

Function: find-file-name-handler file operation
This function returns the handler function for file name file, or nil if there is none. The argument operation should be the operation to be performed on the file--the value you will pass to the handler as its first argument when you call it. The operation is needed for comparison with inhibit-file-name-operation.

Function: file-local-copy filename
This function copies file filename to an ordinary non-magic file, if it isn't one already.

If filename specifies a magic file name, which programs outside Emacs cannot directly read or write, this copies the contents to an ordinary file and returns that file's name.

If filename is an ordinary file name, not magic, then this function does nothing and returns nil.

Function: unhandled-file-name-directory filename
This function returns the name of a directory that is not magic. It uses the directory part of filename if that is not magic. For a magic file name, it invokes the file name handler, which therefore decides what value to return.

This is useful for running a subprocess; every subprocess must have a non-magic directory to serve as its current directory, and this function is a good way to come up with one.

[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [Top] [Contents] [Index] [ ? ]

25.12 File Format Conversion

The variable format-alist defines a list of file formats, which describe textual representations used in files for the data (text, text-properties, and possibly other information) in an Emacs buffer. Emacs performs format conversion if appropriate when reading and writing files.

Variable: format-alist
This list contains one format definition for each defined file format.

Each format definition is a list of this form:

(name doc-string regexp from-fn to-fn modify mode-fn)

Here is what the elements in a format definition mean:

The name of this format.

A documentation string for the format.

A regular expression which is used to recognize files represented in this format.

A shell command or function to decode data in this format (to convert file data into the usual Emacs data representation).

A shell command is represented as a string; Emacs runs the command as a filter to perform the conversion.

If from-fn is a function, it is called with two arguments, begin and end, which specify the part of the buffer it should convert. It should convert the text by editing it in place. Since this can change the length of the text, from-fn should return the modified end position.

One responsibility of from-fn is to make sure that the beginning of the file no longer matches regexp. Otherwise it is likely to get called again.

A shell command or function to encode data in this format--that is, to convert the usual Emacs data representation into this format.

If to-fn is a string, it is a shell command; Emacs runs the command as a filter to perform the conversion.

If to-fn is a function, it is called with two arguments, begin and end, which specify the part of the buffer it should convert. There are two ways it can do the conversion:

A flag, t if the encoding function modifies the buffer, and nil if it works by returning a list of annotations.

A minor-mode function to call after visiting a file converted from this format. The function is called with one argument, the integer 1; that tells a minor-mode function to enable the mode.

The function insert-file-contents automatically recognizes file formats when it reads the specified file. It checks the text of the beginning of the file against the regular expressions of the format definitions, and if it finds a match, it calls the decoding function for that format. Then it checks all the known formats over again. It keeps checking them until none of them is applicable.

Visiting a file, with find-file-noselect or the commands that use it, performs conversion likewise (because it calls insert-file-contents); it also calls the mode function for each format that it decodes. It stores a list of the format names in the buffer-local variable buffer-file-format.

Variable: buffer-file-format
This variable states the format of the visited file. More precisely, this is a list of the file format names that were decoded in the course of visiting the current buffer's file. It is always buffer-local in all buffers.

When write-region writes data into a file, it first calls the encoding functions for the formats listed in buffer-file-format, in the order of appearance in the list.

Command: format-write-file file format
This command writes the current buffer contents into the file file in format format, and makes that format the default for future saves of the buffer. The argument format is a list of format names.

Command: format-find-file file format
This command finds the file file, converting it according to format format. It also makes format the default if the buffer is saved later.

The argument format is a list of format names. If format is nil, no conversion takes place. Interactively, typing just RET for format specifies nil.

Command: format-insert-file file format &optional beg end
This command inserts the contents of file file, converting it according to format format. If beg and end are non-nil, they specify which part of the file to read, as in insert-file-contents (see section 25.3 Reading from Files).

The return value is like what insert-file-contents returns: a list of the absolute file name and the length of the data inserted (after conversion).

The argument format is a list of format names. If format is nil, no conversion takes place. Interactively, typing just RET for format specifies nil.

Variable: auto-save-file-format
This variable specifies the format to use for auto-saving. Its value is a list of format names, just like the value of buffer-file-format; however, it is used instead of buffer-file-format for writing auto-save files. This variable is always buffer-local in all buffers.

[ << ] [ >> ]           [Top] [Contents] [Index] [ ? ]

This document was generated by Dohn Arms on March, 6 2005 using texi2html